Quick PC 61/Quick PC 61.iso/I386/WMS.CAB/wireless.asp

Text File | 2003-02-21 | 9.3 KB | 270 lines

<%@ Language=VBScript CODEPAGE=65001 %>
<!--#include file="include/wmsLocStrings.inc"-->
<!--#include file="include/wmsCommon.inc"-->
<!--#include file="include/wmsHeader.inc"-->
<!--#include file="include/wmsPageBanner.inc"-->
<!--#include file="include/wmsServerHash.inc"-->
<!--#include file="include/wmsPlugins.inc"-->
<!--#include file="include/wmsError.inc"-->
<%
'+-------------------------------------------------------------------------
'
'  Microsoft Windows Media
'  Copyright (C) Microsoft Corporation. All rights reserved.
'
'  File:       Wireless.asp
'
'  Contents:
'
'--------------------------------------------------------------------------

ConnectToServer
ConnectToPubPoint

Dim strTitleString
Dim strHelpString
Dim dwDisplayMode
Dim strPackets
Dim strOp

Dim dwFECPackets

Const SHOWING_FEC = 0

dwDisplayMode = SHOWING_FEC

if( IsEmpty( g_objPubPoint ) ) then
    Server.Transfer( "pubpoint_collection.asp" )
end if

strOp = RemoveDangerousCharacters( qs("op") )
strPackets = RemoveDangerousCharacters( GetFormStr("packets") )

BeginErrorHandling
dwPPType = g_objPubPoint.Type
dwFECPackets = g_objPubPoint.limits.FECPacketSpan

dwDisplayMode = SHOWING_FEC

if( 0 < Len( strOp ) ) then
    if( 0 = StrComp( strOp, "disable", vbTextCompare ) ) then
        g_objPubPoint.EnableFEC = FALSE
        Response.Redirect( "pubpoint_props.asp?server=" & g_strQueryStringServer & "&category=" & g_strCategory & "&instance=" & g_strEncodedInstance & "&ppID=" & g_strPubPointID )
        Response.Flush
    elseif( 0 = StrComp( strOp, "enable", vbTextCompare ) ) then
        g_objPubPoint.EnableFEC = TRUE
        Response.Redirect( "pubpoint_props.asp?server=" & g_strQueryStringServer & "&category=" & g_strCategory & "&instance=" & g_strEncodedInstance & "&ppID=" & g_strPubPointID )
        Response.Flush
    end if
end if

if( "" <> strPackets ) then
    if( ( 0 < CDbl( strPackets ) ) and ( 24 >= CDbl( strPackets ) ) ) then
        g_objPubPoint.limits.FECPacketSpan = strPackets
    end if
    if( 0 = err.number ) then
        Response.Redirect( "pubpoint_props.asp?server=" & g_strQueryStringServer &  "&ppID=" & g_strPubPointID & "&category=" & g_strCategory & "&instance=" & g_strEncodedInstance )
    end if
elseif( 0 <> StrComp( "properties", strOp, vbTextCompare ) ) then
    Response.Redirect( "pubpoint_props.asp?server=" & g_strQueryStringServer &  "&ppID=" & g_strPubPointID & "&category=" & g_strCategory & "&instance=" & g_strEncodedInstance )
end if

if( SHOWING_FEC = dwDisplayMode ) then
    strTitleString = L_FECPROPPAGENAME_TEXT
    if( "" = strPackets ) then
        dwFECPackets = g_objPubPoint.limits.FECPacketSpan
    else
        dwFECPackets = strPackets
    end if

    strHelpString = L_FECPROPPAGEHELP_TEXT
end if

WriteHTMLHeader( Server.HTMLEncode( g_strDecodedInstance ) ) %>
<% WritePluginJSUtils %>
<link rel="stylesheet" type="text/css" href="<%= Session( "cssName" ) %>">
<script language="JavaScript">
<!--
/*@cc_on @*/
var g_bInvalidEntryWarningShown = false;
var g_bMaxSizeExceededWarnShown = false;

//////////////////////////////////////////////////////////////////////////
function ValidatePacketSpan( theEditBox )
{
    <% jsTRY %>
        if( ! theEditBox )
        {
            return false;
        }

        var dwPktSpanEntry = 0;

        if( isNaN( theEditBox.value ) )
        {
            var szPktColor = new String( document.pluginForm.packets.style.color );

            //
            // IE uses standard HTML color values; Netscape 6.x uses rgb colors
            //
            if( ( ! g_bInvalidEntryWarningShown ) && ( ( szPktColor == "#000000" ) || ( szPktColor == "" ) || ( szPktColor == "rgb(0,0,0)" ) ) )
            {
                g_bInvalidEntryWarningShown = true;
                window.alert( "<%= RemoveDangerousCharacters( L_INVALIDENTRY_TEXT ) %>" );
            }
            document.pluginForm.packets.style.color = "#ff0000";
            document.forms.pluginForm.ok.disabled = true;
            return true;
        }
        else
        {
            g_bInvalidEntryWarningShown = false;
        }

        dwPktSpanEntry = new Number( theEditBox.value );

        if( 24 < dwPktSpanEntry )
        {
            if( ! g_bMaxSizeExceededWarnShown )
            {
                g_bMaxSizeExceededWarnShown = true;
                window.alert( "<%= RemoveDangerousCharacters( L_FECPKTSPANTOOBIG_TEXT ) %>" );
            }
            theEditBox.value = "24";
            document.pluginForm.packets.style.color = "#000000";
            document.forms.pluginForm.ok.disabled = false;
            return true;
        }

        if( 0 == dwPktSpanEntry )
        {
            document.pluginForm.packets.style.color = "#000000";
            document.forms.pluginForm.ok.disabled = true;
            return false;
        }

        if( 0 > dwPktSpanEntry )
        {
            theEditBox.value = "0";
            document.pluginForm.packets.style.color = "#000000";
            document.forms.pluginForm.ok.disabled = true;
            return false;
        }

        document.pluginForm.packets.style.color = "#000000";
        document.forms.pluginForm.ok.disabled = false;
        return false;
    <% jsCATCH %>
}
-->
</script>
</head>
<body class="pluginbody" oncontextmenu="JavaScript:event.cancelBubble=true;return false;">
<% DrawPropPageBanner strTitleString %>
<table width="90%">
<tr>
    <td valign="top">

        <% WriteStdPluginForm %>

        <table class="propgroupbox" width="90%" cellspacing="0" cellpadding="3">
        <tr>
            <td>
                <div class="helptext"><%= Server.HTMLEncode( strHelpString ) %></div><br>
            </td>
        </tr>
        <tr>
            <td>
        <%
        if ( SHOWING_FEC = dwDisplayMode ) then
        %>
                <table cellspacing="1" cellpadding="0" border="0">
                <tr>
                    <td>
                        <%= Server.HTMLEncode( L_FECPKTSPERSPAN_TEXT ) %>
                    </td>
                    <td>

                    </td>
                    <td>
                    <input type="text"
                           name="packets"
                           value="<%= Server.HTMLEncode( dwFECPackets ) %>"
                           tabindex=<%= dwTabIndex %> <% dwTabIndex = dwTabIndex + 1 %>
                           onChange="JavaScript:ValidatePacketSpan( this );"
                           onPaste="JavaScript:ValidatePacketSpan( this );"
                           onKeyUp="JavaScript:ValidatePacketSpan( this );"
                           >
                    </td>
                </tr>
                </table>

                <table cellspacing="1" cellpadding="0" border="0">
                <tr>
                    <td>
                         <br>
                        <table class="defaultcursor" cellspacing="2" cellpadding="2" border="1" cols="3">
                        <tr>
                            <td align="left">
                                <table class="defaultcursor" cellspacing="2" cellpadding="2" border="0" cols="3">
                                <tr>
                                    <td align="left" width="32">
                                        <img src="img/wmstip_32.gif" height="32" width="32">
                                    </td>
                                    <td align="left">
                                        <span class="helptext"><%= Server.HTMLEncode( L_FECTIP_TEXT ) %></span>
                                    </td>
                                    <td align="right">

                                    </td>
                                </tr>
                                </table>
                            </td>
                        </tr>
                        </table>
                    </td>
                </tr>
                </table>
            </td>
        </tr>
        </table>
        <%
        end if %>
    </td>
</tr>
<tr>
    <td valign=bottom>
        <input type="submit" align="baseline" name="ok" tabIndex=<%= dwTabIndex %> <% dwTabIndex = dwTabIndex + 1 %>  value="<%= Server.HTMLEncode( L_OKAYBUTTON_TEXT ) %>">
        <input type="button" align="baseline" name="cancel" tabIndex=<%= dwTabIndex %> <% dwTabIndex = dwTabIndex + 1 %>  onclick="JavaScript:Cancel()" value="<%= Server.HTMLEncode( L_CANCELBUTTONSPACED_TEXT ) %>">
        <input type="button" align="baseline" name="help" tabIndex=<%= dwTabIndex %> <% dwTabIndex = dwTabIndex + 1 %>  onclick="JavaScript:DoPluginHelp( '<%= H_WIRELESSHELPTOPIC %>' )" value="<%= Server.HTMLEncode( L_HELPBUTTONSPACED_TEXT ) %>" id="help">
    </td>
</tr>
</table>
</font>
</form>

<% if ( SHOWING_FEC = dwDisplayMode ) then %>
<script language="JavaScript">
<!--
/*@cc_on @*/
    <% jsTRY %>
        document.pluginForm.packets.focus();
    <% jsCATCH %>
-->
</script>
<% end if

AlertUserWithPopupErrorDialog
OnErrorGoBack
DrawCopyrightInfo
DrawStdFooter
%>
</body>
</html>
<%
LatchCurrentPage "pubpoints/wireless.asp", qs
EndErrorHandling "Wireless.asp"

PluginsASPCleanup
%>